So, what happens if you want to display some dynamic data, say some information that you get from a level script, on your HUD?
Note that before you attempt any changes to your hud.gui... I've created a custom HUD in a mod directory... that is, I'm using +set fs_game MOD so that I don't make any changes to my vanilla game's HUD. If you want to muck around with changing your HUD, I highly recommend using +set fs_game too, so you don't mistakenly foobar your Doom3 HUD. You have been warned.
Okay, with that out of the way, let me describe my setup:
I had created a level script that counted the number of times a moveable entity hit the ground. I tracked this number using the technique written about here:
http://www.doom3world.org/phpbb2/viewtopic.php?p=31028
In that post, I basically just describe how to detect when a moveable object hits a trigger, and when the trigger activates, it calls a level script function.
So in this particular case, the script just counts the number of times a moveable ball object hits the floor. I then store that information into my ball entity as a key/value that I can easily retrieve at a later time.
Using that information, I then wanted to plug the number of times my ball object contacts the floor into my HUD and have it update dynamically. To do this, I had to make a few changes to my map:
1. I renamed the info_player_start entity so I could easily reference it in a script...
2. I added a key/value pair to my player entity:
Key: hitcount
Value: 0
3. I explicitely defined the GUI in the info_player_start entity...
EDIT: As in:
Key: gui
Value: guis/hud.gui
on the info_player_start entity.
/EDIT
This step is what allows you to reference gui parms with your player... without it, any key/value pairs you try to update via scripts won't change on the HUD. I imagine there's a more elegant way to get around this issue, but I haven't found it yet. On the other hand, if you were doing this for any other GUI, this step would be required... after all, without it, Doom3 doesn't know what GUI to apply to your object....
With those changes, let's move on to the scripts:
Here's a cut-down version of my level script (leaving out parts that don't pertain to this topic (and note that this script is far from polished!)). Also note that the myfloorhits() function is only about 5 lines of actual code... I've just added comments so you can tell what each statement does:
tt1.script:
Code:
// collision detection and script-to-HUD level script test
void setup_objects() {
// empty
}
void myfloorhit() {
// init hit counter var
float hc = 0; // script hit counter
// The number of hits gets stored into the ball entity
// each time the function is called...
// So we start by copying the value of our ballhits entity key
// into the hit counter variable so that we can add to
// the previous value
hc = $myspball.getIntKey("ballhits");
// since this function only gets called when the ball hits
// the target area, we can increase the value of hits now
hc++;
// SET GUI PARM
// This is the meat of our script-to-GUI interaction...
// all we're doing is setting the a GUI parameter to
// the current hit count value.
//
// Since we want to update the player's hud, we've renamed the
// info_player_start entity to:
//
// "spplayer"
//
// and added a key called:
//
// "hitcount"
//
// with an initial value of 0.
//
// That allows the use of the setGuiParm() function with
// our player's HUD...
//
// Basically, just store the value of the "hc" script
// variable into the GUI parm "hitcount"
$spplayer.setGuiParm( "hitcount", hc );
// now store the hit count value back into the ball entity
// using our "ballhits" key so that it will be available the
// next time the function gets called...
$myspball.setKey("ballhits", hc);
// END
}
void initfloorhits() {
// initialize the GUI parm
$spplayer.setGuiParm( "hitcount", 0 );
}
void main() {
initfloorhits();
}
void setup_objects() {
// empty
}
void myfloorhit() {
// init hit counter var
float hc = 0; // script hit counter
// The number of hits gets stored into the ball entity
// each time the function is called...
// So we start by copying the value of our ballhits entity key
// into the hit counter variable so that we can add to
// the previous value
hc = $myspball.getIntKey("ballhits");
// since this function only gets called when the ball hits
// the target area, we can increase the value of hits now
hc++;
// SET GUI PARM
// This is the meat of our script-to-GUI interaction...
// all we're doing is setting the a GUI parameter to
// the current hit count value.
//
// Since we want to update the player's hud, we've renamed the
// info_player_start entity to:
//
// "spplayer"
//
// and added a key called:
//
// "hitcount"
//
// with an initial value of 0.
//
// That allows the use of the setGuiParm() function with
// our player's HUD...
//
// Basically, just store the value of the "hc" script
// variable into the GUI parm "hitcount"
$spplayer.setGuiParm( "hitcount", hc );
// now store the hit count value back into the ball entity
// using our "ballhits" key so that it will be available the
// next time the function gets called...
$myspball.setKey("ballhits", hc);
// END
}
void initfloorhits() {
// initialize the GUI parm
$spplayer.setGuiParm( "hitcount", 0 );
}
void main() {
initfloorhits();
}
And here's the GUI:
hud.gui (make sure you don't overwrite your vanilla game's HUD)
Code:
// A custom player hud
windowDef Desktop {
rect 0 ,0 ,640 ,480
backcolor 0 ,0 ,0 ,0
visible 1
nocursor 1
onEvent {
// on any event, update the HUD hit count text string
// with the gui parm "hitcount"
//
// "hitcount" is passed via a level script using
// the setParm() function.
//
// Note: To access a GUI parm, you use:
// "gui::xxxxx", where xxxxx is the
// entity key passed by the setParm
// script function...
set "hitcountText::text" "gui::hitcount"
}
// "Floor Hits:" text
windowDef HitsText {
rect 3,377,131,36
visible 1
nocursor 1
forecolor 1,1,0,1
text "Floor Hits:"
textscale 0.5
nowrap 1
noevents 1
}
// Dynamic script data:
windowDef hitCountText {
rect 137,376,65,38
visible 1
nocursor 1
forecolor 1,1,0,1
text "blah blah" // this will be overwritten by the level script
textscale 0.5
nowrap 1
noevents 1
}
// Version info text
windowDef versionInfo {
rect 3,445,159,31
visible 1
noevents 1
nocursor 1
forecolor 1,1,1,1
text "Balloon Bop/ Smash Ball\nv0.1"
textscale 0.2
backcolor 0,0.25098041,0.50196081,0.71764708
bordersize 1
bordercolor 1,1,0,1
}
}
windowDef Desktop {
rect 0 ,0 ,640 ,480
backcolor 0 ,0 ,0 ,0
visible 1
nocursor 1
onEvent {
// on any event, update the HUD hit count text string
// with the gui parm "hitcount"
//
// "hitcount" is passed via a level script using
// the setParm() function.
//
// Note: To access a GUI parm, you use:
// "gui::xxxxx", where xxxxx is the
// entity key passed by the setParm
// script function...
set "hitcountText::text" "gui::hitcount"
}
// "Floor Hits:" text
windowDef HitsText {
rect 3,377,131,36
visible 1
nocursor 1
forecolor 1,1,0,1
text "Floor Hits:"
textscale 0.5
nowrap 1
noevents 1
}
// Dynamic script data:
windowDef hitCountText {
rect 137,376,65,38
visible 1
nocursor 1
forecolor 1,1,0,1
text "blah blah" // this will be overwritten by the level script
textscale 0.5
nowrap 1
noevents 1
}
// Version info text
windowDef versionInfo {
rect 3,445,159,31
visible 1
noevents 1
nocursor 1
forecolor 1,1,1,1
text "Balloon Bop/ Smash Ball\nv0.1"
textscale 0.2
backcolor 0,0.25098041,0.50196081,0.71764708
bordersize 1
bordercolor 1,1,0,1
}
}
So that's one way to get level script variable data into a custom HUD. This will, of course, also work for any GUI by simply changing the entity named for the setParm() function and updating the gui key's value for your GUI entity with whatever gui script file and custom data you choose.
HUD - 0 Hits
HUD - 3 Hits
Hope this helps some folks.
Goliath
, so wasnt sure what you needed).